Начнем с терминологии, ибо это наш язык общения в технологическом плане.
dint - средний диаметр частиц по интервалу. Интервал это диапазон размеров частиц в остатке между двумя смежными ситами. Если предыдущее сверху сито имеет диаметр ячеек d1 и последующее - диаметр d2, то интервал будет d1--d2, а среднее по интервалу лежит в пределах d1--d2. Без большой погрешности для расчетных результатов (я это специально проверял) можно принять dint=(d1+d2)/2.
d_средн - средний диаметр частиц по всей навеске (пробе). Математически его можно определить как Sdint*Pint/P, где P и Pint веса пробы и в интервале (остаток на сите). Если вес выражен в процентах, то такое среднее можно более точно назвать средневзвешенным по весовому проценту.
d80, d50 и d10 - диаметры ячеек сит, через которые просеивается соответственно 80, 50 и 10% всех фракций. Если бы у нас были сита с точно такими диаметрами ячеек, то это были бы диаметры, равные d2, т.е. меньшему из диаметров в интервале d1--d2.
Все перечисленные диаметры имеют четкий физический смысл и их, в принципе, можно измерить непосредственно, без всяких перекруток, чего не скажешь о таком изобретении наукообразной мысли, как "эквивалентный диаметр", бытующий в нормативных документах уже много лет. У этого "диаметра" ряд недостатков:
терминологический: просто эквивалентных величин не бывает, а бывают величины, эквивалентные чему-то. Один г-экв кислоты эквивалентен одному г-молю соляной кислоты и половине г-моля серной кислоты. Эквивалентный диаметр трубы эллипсного сечения эквивалентен диаметру трубы круглого сечения, при котором гидравлическое сопротивление труб будет одинаковым при их равной длине. И т.д. и т.п.
физический: не вдруг сообразишь, что же это такое в плане физического смысла. А это - среднее по всей навеске значение 1/d, возведенное в минус первую степень.
коммукационный: попробуй объяснить снабженцу что это такое "эквивалентный диаметр", в любом варианте объяснения он заподозрит надувательство или подвох.
технологический и главный: значения этого показателя зависят от условий проведения рассева в гораздо большей степени, чем значения d_средн.
Представим, что у нас есть десять порций остатков, каждая по 10 г и с диаметрами частиц dint, равными 1, 2, 3, 4, 5, 6, 7, 8, 9 и 10 мм. Тогда
d_средн=(1*10+2*10+3*10+4*10+5*10+6*10+7*10+8*10+9*10+10*10)/100,
что составит 5,5 мм;
d_эфф=100/(10/1+10/2+10/3+10/4+10/5+10/6+10/7+10/8+10/9+10/10),
что составит 3,414 мм.
Теперь "возьмем" меньшее количество сит на ту же навеску - объединим фракции 1 и 2, 3 и 4 и т.д.:
d_средн=(1,5*20+3,5*20+5,5*20+7,5*20+9,5*20)/100 = 5,5
d_эфф=100/(20/1,5+20/3,5+20/5,5+20/7,5+20/9,5) = 3,642
"Заменим" первую фракцию на более мелкую:
d_средн=(0,5*20+3,5*20+5,5*20+7,5*20+9,5*20)/100 = 5,3
d_эфф=100/(20/0,5+20/3,5+20/5,5+20/7,5+20/9,5) = 1,848
И т.д., и т.п., и прочее...
Итог. Средний диаметр характеризует ясно что. Коэффициент неоднородности характеризует разброс относительно среднего диаметра. Оба эти показателя, если не придираться к мелким погрешностям расчетов, не зависят от набора используемых при рассеве сит. "Эквивалентный" же диаметр зависит и от среднего диаметра, и от коэффициента неоднородности, и от набора используемых при рассеве сит. Это "диаметр", характеризующий неизвестно что, хотя в узких пределах фракционного состава он и близок к средней величине.
И вообще. Зачем здравомыслящим согражданам использовать показатель, единственным "достоинством" которого является то, что "Он примерно равен средней величине диаметра частиц". И это при том, что ничто не мешает определять величину средне- го диаметра, которая уж точно, без всяких оговорок равна самой себе.
Однако так или иначе, но определение "эквивалентного" диаметра это уже традиция, а с традициями приходится считаться. Поэтому мне пришлось немного переделать функцию пользователя и я привожу здесь ее скорректированный текст. Исправленная функция пользователя работает в данном файле Rassev2.xls, а прежний вариант функции остался в файле Rassev.xls.
Текст функции пользователя записан на Visual Basik и она может использоваться наряду со стандартными функциями приложения Excel, входящего в пакет Microsoft Office.
Function Rassev(ms)
ms = ms 'переводим исходный массив данных ms во внутреннее представление
jk = UBound(ms, 1) 'определяем количество строк в ms
ReDim msr(1 To jk + 7, 1 To 3) 'указываем размерность массива результатов msr
'Оформляем первую строку msr
msr(1, 1) = "": msr(1, 2) = "": msr(1, 3) = 100
'Находим значения dint:
For j = 2 To jk
msr(j, 1) = (ms(j - 1, 1) + ms(j, 1)) / 2
Next
'Находим значения P%:
Sum = 0
For j = 1 To jk
Sum = Sum + ms(j, 2)
Next
For j = 2 To jk
msr(j, 2) = ms(j, 2) / Sum * 100
Next
'Находим значения Q%:
For j = 2 To jk
msr(j, 3) = msr(j - 1, 3) - msr(j, 2)
Next
'Заносим обозначения, дооформляем msr
msr(jk + 1, 2) = " ---": msr(jk + 1, 3) = " ---"
For j = jk + 1 To jk + 7
msr(j, 1) = ""
Next
am = Array("d_сред", "d80", "d50", "d10", "Kn", "d_экв")
For j = 1 To 6
msr(jk + 1 + j, 2) = am(j - 1)
Next
'Определяем d_сред:
sumpr = 0
For j = 2 To jk
sumpr = sumpr + msr(j, 1) * msr(j, 2)
Next
msr(jk + 2, 3) = sumpr / 100
'Находим адреса d1 для d80, d50 и d10:
j80 = 1: j50 = 1: j10 = 1
For j = 2 To jk
a = msr(j, 3)
j80 = IIf(a < 80 And j80 = 1, j, j80)
j50 = IIf(a < 50 And j50 = 1, j, j50)
j10 = IIf(a < 10 And j10 = 1, j, j10)
Next
'Определяем значения d80, d50, d10 и Kn:
msr(jk+3,3)=ms(j80,1)+(ms(j80-1,1)-ms(j80,1))/(msr(j80-1,3)-msr(j80,3))*(80-msr(j80,3))
msr(jk+4,3)=ms(j50,1)+(ms(j50-1,1)-ms(j50,1))/(msr(j50-1,3)-msr(j50,3))*(50-msr(j50,3))
msr(jk+5,3)=ms(j10,1)+(ms(j10-1,1)-ms(j10,1))/(msr(j10-1,3)-msr(j10,3))*(10-msr(j10,3))
msr(jk + 6, 3) = msr(jk + 3, 3) / msr(jk + 5, 3)
'Устраняем возможные отрицательные значения Q%,
'которые могут возникнуть из-за погрешностей машинного расчета:
For j = 2 To jk
a = msr(j, 3)
msr(j, 3) = IIf(a < 10^-10, 0, a)
Next
'Определяем d_экв:
sumpr = 0
For j = 2 To jk
sumpr = sumpr + msr(j, 2)/ msr(j, 1)
Next
msr(jk + 7, 3) = 100/sumpr
'Присваиваем значения msr функции Rassev:
Rassev = msr
End Function
Варианты этой и других функций смотри в прилагаемых файлах Excel – файлы RASSEV.XLS, RASSEV2.XLS и RASSEV3.XLS.